Modulo 3, exercício 54 – Fundamentos da programação

Olá Bruno, no que eu entendi, quando na feitura do programa se você fizer por etapas como cadenciou no inicio, ele vai funcionar normal, até você partir para
validação, pois colocara a cadeia teclado na jogada e será perdidas as referências nome, idade e resp. por isso deve ser inicializadas essas variáveis, não se trata de gambiarra. fica tranquilo,
cadeia nome = “”
inteiro idade = 0
resp = ‘ ‘
Se tiver outra informação me passe, mas esse é meu entendimento você não errou em nada. Bons estudos. E desistir não é uma opção!

Desculpe.
caracter resp = ‘ ‘

Bruno, o seu código está bom e isso não é de forma alguma uma gambiarra. A questão ai é que as vezes o compilador precisa ter certeza que a variável não está vazia, pois como todos são inicializadas em blocos condicionais se não é possível saber se a execução entrará em um bloco e iniciará a variável. Se houvesse um senao onde a variável fosse inicializada isso garantiria que se a execução não entrar nos blocos se, ou seja, se os valores inseridos não pertencerem a nenhuma condição, a variável seria inicializada mesmo assim. Mas nessa questão não há como inserir um senão e manter a lógica.

Por conta do enquanto(verdadeiro) sabemos que as variáveis vão ser sempre inicializadas, mas o programa enxerga apenas a questão que mencionei sobre os blocos condicionais.
Há várias formas de resolver este problema, mas para não modificar a sua lógica que está boa, basta inicializar as variáveis quando forem declaradas como já foi feito, e novamente, não é uma gambiarra nessa situação, não se preocupe.

Quanto a sua dúvida sobre a contagem de caracteres, o problema está na organização dos blocos condicionais.
Uma cadeia só será caractere se seu tamanho for igual a 1, então não há necessidade de testar isso novamente dentro desse bloco. Basta por um senao no se onde é verificado se é caractere que entrarão no senao todos os casos onde o tamanho for maior que 1.

se (tp.cadeia_e_caracter(teclado)){  //a função só retornará verdadeiro se o tamanho da variável teclado for 1
resp = tp.cadeia_para_caracter(teclado)
}senao
escreva(“\n<<ERRO>> DIGITE APENAS [S\\N]”)  //entrarão aqui todos os casos onde o tamanho da variável teclado não for 1
}

Quaisquer outras dúvidas estamos a disposição.

OLÁ !
NO MOMENTO EM QUE FAÇO A VALIDAÇÃO DE DADOS E SUBSTITUO A VARIÁVEL (NOME) OU (RESP) OU (IDADE) POR (TECLADO ), NO FINAL DA SEMPRE ERRO NO CÓDIGO .
A MESSAGEM DE ERRO É ” EXISTEM TRECHOS DE CÓDIGO ONDE A VARIÁVEL () PODE NÃO TER SIDO INICIALIZADA ” . EU NÃO CONSIGO IDENTIFICAR O ERRRO , SE ALGÉM PODER ME AJUDAR AGRADEÇO : ) copiei um trecho do código abaixo
enquanto (verdadeiro){
escreva(“IDADE : “)
leia (teclado)
se (t.cadeia_e_inteiro(teclado,10)){
idade = t.cadeia_para_inteiro(teclado,10)
se(idade>=1 e idade <=130){
pare
}senao{
escreva(“<<Erro>> Idade inválida\n”)
}
}senao{
escreva(“<<Erro>> A idade deve ser um numero inteiro\n “)
}
}

– Boa tarde! Katia, não consegui verificar, observe se no indicativo de erro não está aparecendo a linha, como você não mandou o código todo não sei dizer, mas geralmente nestes casos, tudo está normal, até acrescentar a variável teclado.
– Observe você lançou a variável teclado como cadeia?
– Se lançou como ela entrou no meio entre as variáveis, nome, resp e idade estas tem que ser inicializadas com um valor:
cadeia nome = ” ”
caracter resp = ‘ ‘
Talvez
inteiro idade = 0
Do mais só observando o código todo. Espero ter ajudado. Desistir não é uma opção! Bom estudos!

Bom dia Katia, eu já postei uma explicação no forum a respeito de variável não inicializada.
Conforme Francisco falou, você provavelmente criou uma variável sem valor e quando o programa inicializa e faz a verificação, ele se depara com isso.
Então basta inicializa-las conforme dito pelo amigo.
Caso isso não ocorra, por favor poste o código completo para verificarmos junto a você.
PS: Use a formatação CODE no forum para postar os códigos, assim não precisaremos corrigir os espaços e aspas caso precisemos polo no Portugal Studio.

Fala pessoal, tudo tranquilo?
alguém pode me ajudar?? Estava tendo um pouco de dificuldade no exercício 54 do modulo 3 por isso resolvi dar uma olhada na resposta. Porém copiei o exercício igual ao vídeo da aula do mestre Guanabara e não está executando igual o dele. No meu o portugol aponta erro de compilação devido as variáveis NOME, IDADE e RESP e ter sido inicializadas. Porém no vídeo elas também não foram. Aí quando inicializo elas o programa roda.
Segue abaixo o código que copiei e que inicializei as variáveis NOME, IDADE e RESP para que ele funcionasse. Caso alguém note uma diferença com o código do professor pode deixa o feedback por favor. (Estou revisando esse codigo faz 3 dias)

programa
{
	inclua biblioteca Tipos --> t
	inclua biblioteca Texto --> txt
 	funcao inicio()
	{
		escreva("{ EXERCÍCIO 054 - Pessoas Validadas }\n\n")
		
		cadeia teclado, nome = "", jovem = "", velho = ""
		inteiro idade = 0, cont = 0, maior = 0, menor = 0
		caracter resp = ' '
		
		faca{//ENTRADA DE DADOS COM VALIDAÇÃO
			escreva("---------------------\n")
			escreva("      PESSOA " + (cont + 1) + "\n")
			escreva("---------------------\n")
			
			enquanto (verdadeiro) {
				escreva("NOME = ")
				leia(teclado)
				se (txt.numero_caracteres(teclado) >= 3) {
					nome = teclado
					pare
				} senao {
					escreva("<<ERRO>> O nome deve ter pelo menor 3 letras.\n")
				}
			}

			enquanto (verdadeiro) {
				escreva("IDADE = ")
				leia(teclado)
				se (t.cadeia_e_inteiro(teclado, 10)) {
					idade = t.cadeia_para_inteiro(teclado, 10)	
					se (idade >= 3 e idade <= 130) {
						pare	
					} senao {
						escreva("<<ERRO>> Idade inválida.\n")
					}
				} senao {
					escreva("<<ERRO>> A idade deve ser um número inteiro.\n")
				}
			}
			cont++
			se (cont == 1) {//SE FOR A PRIMEIRA PESSOA
				maior = idade
				menor = idade
				jovem = nome
				velho = nome
			} senao {//SE NÃO FOR A PRIEMEIRA PESSOA
				se (idade > maior) {
					maior = idade
					velho = nome
				}
				se (idade < menor) {
					menor = idade
					jovem = nome
				}
			}

			enquanto (verdadeiro) {
				escreva("Que continuar? [S/N] ")
				leia(teclado)
				se(t.cadeia_e_caracter(teclado)) {
					resp = t.cadeia_para_caracter(teclado)
					se(resp == 'S' ou resp == 's' ou resp == 'N' ou resp == 'n') {
						pare
					} senao {
						escreva("<<ERRO>> Resposta inválida! Digite apena 'S' ou 'N'.\n")
					}
				} senao {
					escreva("<<ERRO>> O valor deve ser apenas uma letra.\n")
				}
			}
		} enquanto( resp == 'S' ou resp == 's')
		escreva("=========================================\n")
		escreva("Você cadastro " + cont + " pessoas.\n")
		escreva(jovem + " é a pessoa mais nova com " + menor + " anos.\n")
		escreva(velho + " é a pessoa mair velha  com " + maior + " anos.\n")
		escreva("==========================================\n\n")
	}
		
}