Dúvida Exercício 42 (Repetições)

Bom dia.
O problema esta na sequencia logica das condições.
Todos os cálculos efetuados após o PARE não serão realizados, pois irá sair do loop.

1º- você pode organizar tds as entradas e depois fazer as validações:

escreva("Nome :")
leia(nome)
escreva("Sexo [M/F] :")
leia(sexo)
escreva("Salário :")
leia(salario)

2º – A media salarial pode ser realizada dentro do checador de sexo, tendo em vista que so será realizada para os homens. (vc estava fazendo com o salario geral)

se (sexo == "M" ou sexo == "m"){
    somah++
    mediaSalarial = (mediaSalarial + salario) / somah
}

3º para o total de mulheres que ganham acima de 1000:

senao se (sexo == "F" ou sexo == "f"){
    somam++   
    se (salario > 1000){
        totalM ++
    }
}

4º maior salario homens:

se (sexo == "M" ou sexo == "m"){
    somah++
    mediaSalarial = (mediaSalarial + salario) / somah
    se (salario > maiorsalarioM){
        maiorsalarioM = salario
    }
}

Código completo:

programa
{
	funcao inicio()
	{
		inteiro contador = 0 , somah = 0 , somam = 0, totalM = 0
		real salario = 0.0, mediaSalarial = 0.0, somasalario = 0.0, maiorsalarioM = 0.0
		cadeia nome, sexo, continuar

		enquanto (verdadeiro) {
			escreva("Nome :")
			leia(nome)
			escreva("Sexo [M/F] :")
			leia(sexo)
			escreva("Salário :")
			leia(salario)

			se (sexo == "M" ou sexo == "m"){
				somah++
				mediaSalarial = (mediaSalarial + salario) / somah
				se (salario > maiorsalarioM){
					maiorsalarioM = salario
				}
			}
			senao se (sexo == "F" ou sexo == "f"){
			 	somam++   
			 	se (salario > 1000){
			 		totalM ++
			 	}
			}
			escreva("Quer continuar [S/N]?")
			leia(continuar)
			contador++
			// Condição de parada
			se (continuar == "N" ou continuar == "n"){
				pare
			} 
		}
		escreva("\n========= RESULTADOS ========")
		escreva("\nTotal de Pessoas Cadastradas :" + contador)
		escreva("\nTotal de Homens: " + somah)
		escreva("\nTotal de Mulheres: " + somam)
		escreva("\nMédia salarial dos homens: " + mediaSalarial)
		escreva("\nTotal de mulheres que ganham mais de Mil Reais: " + totalM)
		escreva("\nMaior salário entre os homens: " + maiorsalarioM)
	}
}

OBS: Sempre que postar seus códigos aqui, formate-os através da aba de formatação de texto. -> CODE