M03A07 – Maior e Menor Valores

aaah, analisei mais um pouco e acabei de encontrar um erro.
caso o usuário digite 0 e coloque ele em qualquer lugar que não seja o no valor final, vai dar erro, então troquei o “v2=0” e o “v2==0” por “v2=-1” e “v2==-1” e parece funcionar tranquilamente agora, mas apenas para números positivos (ou neutro).. mas ver esse erro ja me deu uma boa noção dos meus limites e dos limites do meu programa, desculpe o incômodo..

Modifiquei, e agora está da forma que o professor orientou, tendo em vista que não achei outra maneira mais adequada de fazer:

programa
{
	
	funcao inicio()
	{
		inteiro ctrl=1, v, ma_v=0, me_v=0
		
		escreva("Maior e Menor Valor\n\n")
		
		enquanto (ctrl<=5) {
			escreva("Digite o valor: ")
			leia(v)

			se (ctrl==1) {
				ma_v=v
				me_v=v
			} senao {
				se (ma_v<v) {
					ma_v=v
				}
				se (me_v>v) {
					me_v=v
				}
			}
			
			ctrl++
		}

		escreva("\nMaior: ", ma_v, "\nMenor: ", me_v)
	}
}

Obrigado pelas opiniões, entendi que essa minha solução anterior pode até ser uma solução bacana para outros, mas de fato, não é adequada para o objetivo deste programa.

Eu queria evitar ao máximo ter que usar de coisas como inteiro ma_v=10000000 ou algo do tipo, justamente por não sentir segurança em usar, mas acho que existem excessões, por exemplo, este é o meu código do Exercício 037:

programa
{ // Estudonauta: Programação básica. Módulo 3, Aula 7, Exercício 037. (https://estudonauta.com/)
	
	funcao inicio()
	{
		inteiro ctrl=1, id, ma_id=0, me_id=0
		cadeia nom, ma_ve="mais velho", ma_jo="mais jovem"
		
		escreva("{ EXERCÍCIO 037 - Mais velho e Mais novo }\n")
		
		enquanto (ctrl<=5) {
			escreva("\n-------------------\n", ctrl, "a PESSOA\n-------------------\nNOME: ")
			leia(nom)
			escreva("IDADE: ")
			leia(id)

			se (ma_id<id) {
				ma_id=id
				ma_ve=nom
			}
			se (me_id>id ou me_id==0) {
				me_id=id
				ma_jo=nom
			}

			ctrl++
		}

		escreva("\nA pessoa mais jovem é ", ma_jo, " que tem ", me_id, " anos.\nA Pessoa mais velha é ", ma_ve, " que tem ", ma_id, " anos.")
	}
}

como podem ver, eu usei a idade para orientar todo o código, e usei a minha mesma solução anterior, e para esse caso, eu não acho errado, pois ninguém iria digitar que tem 0 anos, pois não condiz com o objetivo do código. (e mesmo se fizerem essa maldade kkkk, pode-se alterar para orientar o calculo em -1 ao em vez de 0, que ai não dá né, -1 anos de vida é sacanagem kkkk)

é certo pensar dessa forma? posso entender que essa solução torna-se adequada para este código 037, por pegar como base o fato de que ninguém tem 0 (ou -1) anos de vida?

ooh, Ok, muito obrigado pela a ajuda!