Lucas Maciel Francisco

Gostaria de esclarecer algo sobre o exercício 17..

eu fiz desta formna:

se (((ano%4==0 ou ano%400==0) e ano%100!=0) ou (ano%100==0 e ano%400==0)) {
			escreva(" É BISSEXTO!")
		} senao {
			escreva(" NÂO É BISSEXTO!")
		}

e usei estes sites para aprender o que era um ano bissexto e compreender o calculo:

https://escolakids.uol.com.br/matematica/calculo-do-ano-bissexto.htm
https://pt.wikihow.com/Descobrir-se-um-Ano-%C3%A9-Bissexto

minha forma ficou bem parecida com a do professor, com excessão de que ficou maior..
minha pergunta é: desse jeito ficou bom, tendo como base o sistes que me informei? essas linhas a mais são realmente desnecessárias?

Isso começou a acontecer a partir de quando? você se lembra de ter feito alguma modificação nas configurações do portugol?
tem certeza de que não é seu teclado ou o sistema? (quando eu usava windows, as vezes o sistema trocava o idioma do meu teclado, ja que eu instalava 3)
tentou re-instalar o portugol?
pesquisou alguém, no yt, ou mesmo no site do portugol, falando sobre esse erro?

falei tudo o que eu faria se estivesse no seu lugar, desculpe se não consegui ajudar..

Opa, acabei de acabar o exercício 068.. deu um trabalho, e estou me questionando se tem erros no meu código ou se tem algo que eu possa melhorar. Ja que ficou um código relativamente grande, eu estou tendo dificildades de pensar em todas as possibilidades possíveis, então se alguém pudesse dar alguma opnião, seria de grande ajuda!
Aqui está:

programa
{ // Estudonauta: Programação básica. Módulo 4, Aula 14, Exercício 068. (https://estudonauta.com/)
	
	inclua biblioteca Util --> ut
	funcao inicio()
	{
		caracter camp_r[5][5]
		inteiro lin, col, ctrl=1, pon=0, sor[2]
		
		escreva("{ EXERCÍCIO 068 - Jogo Campo Minado }\n\n")

		ut.aguarde(500)
		escreva("==================================\n\tCAMPO MINADO V1.0\n==================================\n\n")

		// gerando "bombas"
		ut.aguarde(1000)
		enquanto (ctrl<=5) {
			sor[0]=sorteia(0,ut.numero_linhas(camp_r)-1)
			sor[1]=sorteia(0, ut.numero_colunas(camp_r)-1)
			se (camp_r[sor[0]][sor[1]]!='O') {
				ctrl++
				camp_r[sor[0]][sor[1]]='O'
			}
		}
		ctrl=1

		// gerando o resto com base na posição das "bombas"
		para (inteiro l=0;l<ut.numero_linhas(camp_r);l++) {
			para (inteiro c=0;c<ut.numero_colunas(camp_r);c++) {
				se (camp_r[l][c]!='O') {
					camp_r[l][c]='-'
				}
			}
		}

		// jogo
		faca {
			para (inteiro l=0;l<ut.numero_linhas(camp_r);l++) {
				para (inteiro c=0;c<ut.numero_colunas(camp_r);c++) {
					ut.aguarde(25)
					se (camp_r[l][c]!='V') {
						escreva("?  ")
					} senao {
						escreva(camp_r[l][c], "  ")
					}
				}
				escreva("\n")
			}

			escreva("------------------------------------\nFaça sua jogada! (Tentativa: ", ctrl,
			")\n")
			
			faca {
				escreva("LINHA = ")
				leia(lin)
			} enquanto (lin>=ut.numero_linhas(camp_r) ou lin<0)
			faca {
				escreva("COLUNA = ")
				leia(col)
			} enquanto (col>=ut.numero_colunas(camp_r) ou col<0)
			
			se (camp_r[lin][col]=='O') {
				ut.aguarde(500)
				escreva("------------------------------------\n\n--> TIRO ERRADO! Acertou uma bomba e PERDEU O JOGO!")
				camp_r[lin][col]='*'
				pare	
			} senao se (camp_r[lin][col]=='V') {
				escreva("\t\t--> Você não pode jogar duas vezes na mesma posição, tente novamente!\n")
			} senao {
				ut.aguarde(500)
				ctrl++
				pon+=2
				escreva("------------------------------------\n\n")
				camp_r[lin][col]='V'
				se (ctrl==6) {
					ctrl--
					escreva("--> VOCÊ GANHOU!")
					pare
				} senao {
					escreva("--> TIRO CERTO! Não acertou nehuma bomba!\n")
				}
			}
		} enquanto (verdadeiro)
	
		// resultados
		escreva("\n\n------------------------------------\nFIM DE JOGO!\n")
		
		para (inteiro l=0;l<ut.numero_linhas(camp_r);l++) {
			para (inteiro c=0;c<ut.numero_colunas(camp_r);c++) {
				ut.aguarde(25)
				escreva(camp_r[l][c], "  ")
			}
			escreva("\n")
		}

		escreva("\nVocê fez ", pon, " pontos em ", ctrl, " tentativas.\n------------------------------------")
	}
}

Yo..
Eu assisti a aula 14 e consegui fazer todos os exercícios, mas com um pouco (ta, talvez mais que apenas “um pouco”) de dificuldade, então por isso vim procurar por soluções de outras pessoas e comparar com as minhas, para tentar amadurecer toda a ideia de aninhamentos.. minha lógica.. e encontrei este post primeiro, onde falava de uma tal pirâmide B. eu ja ia postar meu código para pedir opniões, então com base nesse post, resolvi tentar fazer essa pirâmide B também, e ja mostrar o dois. e eu consegui.. (eu acho?)

programa
{ // Estudonauta: Programação básica. Módulo 3, Aula 14, Exercício 052. (https://estudonauta.com/)
	
	inclua biblioteca Util --> ut
	funcao inicio()
	{
		inteiro an, ctrl, ctrl2, anctrl=0, anctrl2=0
		
		escreva("{ EXERCÍCIO 052 - Pirâmide }\nQuantos andares? ")
		leia(an)
		escreva("\n")
		
		para (ctrl=1;ctrl<=an;ctrl++) {
			se (ctrl==1) {
				anctrl=an*2
			} senao {
				anctrl-=2
			}
			anctrl2++

			para (ctrl2=anctrl2;ctrl2>0;ctrl2--) {
				escreva(" ")
			}
			
			para (ctrl2=anctrl;ctrl2>0;ctrl2--) {
				ut.aguarde(50)
				escreva("*")
			}
			
			escreva("\n")
		}

		escreva("\n")

		anctrl=0
		anctrl2=0
		
		para (ctrl=1;ctrl<=an;ctrl++) {
			se (ctrl==1) {
				anctrl2=an
			} senao {
				anctrl2-=1
			}
			
			anctrl+=2

			para (ctrl2=1;ctrl2<=anctrl2;ctrl2++) {
				escreva(" ")
			}
			
			para (ctrl2=1;ctrl2<=anctrl;ctrl2++) {
				ut.aguarde(50)
				escreva("*")
			}
			escreva("\n")
		}
	}
}

esse é de longe, o código mais confuso que ja fiz até agora. eu gastei um bom tempo nele, evoluindo a partir de pequenos avanços, e depois de pronto, quando deu aquela felicidade de ver o resultado que eu almejava, eu parei para analisar do começo ao fim tudo o que fiz e eu me confudi varias vezes kkkkkkkk
então, não sei se essa confusão é porque eu ainda não dei tempo ao tempo para me acostumar com toda a ideia, ou se o problema é realmente o meu código..